>>  <<  Ркв  Ввд  JfC  LJ  Фрз  Слв  Изм  Рзг  !:  Помощь  Словарь

25. Линейные Функции

Функция f называется линейной, если f(x+y) равно (f x)+(f y) для всех аргументов x и y . Например:
   f=: 3&|. @: +: @: |.
   ]x=: i.# y=:2 3 5 7 11
0 1 2 3 4

   x+y                            f x+y
2 4 7 10 15                    8 4 30 20 14

   (f x),:(f y)                   (f x)+(f y)
2 0  8  6  4                   8 4 30 20 14
6 4 22 14 10
Можно дать и эквивалентное определение: f линейна, если f@:+ и +&f эквивалентны. Например:
   x f@:+ y                       x +&f y
8 4 30 20 14                   8 4 30 20 14
Если f линейна, то f y можно выразить в виде матричного произведения mp&M y , где
   mp=: +/ . *
   M=: f I=: = i.#y            I единичная матрица

   mp&M y
6 4 22 14 10 
   f y
6 4 22 14 10
Обратное тоже верно, если m — любая квадратная матрица порядка #y , то m&mp является линейной функцией y , а если m обратима, то (%.m)&mp — соответствующая обратная функция:

   x=: 1 2 3 [ y=: 2 3 5
   ]m=: ?. 3 3$9
3 8 8
4 2 0
2 7 4
   ]n=: %. m
0.0909091   0.272727 _0.181818
_0.181818 _0.0454545  0.363636
 0.272727 _0.0568182 _0.295455
   
   g=: mp&m
   h=: mp&n
   
   x g@:+ y
45 90 56
   
   x +&g y
45 90 56
    g h y
2 3 5

Упражнения

25.1   Для каждой из перечисленных функций найдите матрицу M , такую что M (mp=: +/ . *) N эквивалентно исходной функции в применении к матрице N . Проверьте для N=: i. 6 6 
|.
-
+:
(4&*-2&*@|.)
2&A.


>>  <<  Ркв  Ввд  JfC  LJ  Фрз  Слв  Изм  Рзг  !:  Помощь  Словарь